Subversion Repositories camp_sysinfo_client_3

#!/usr/bin/env perl
use warnings;
use strict;  

# Description: Gets PCI information on Unix systems if lspci installed

our $VERSION = '1.2';

# pci information for sysinfo client
# Author: R. W. Rodolico
# Date:   2016-04-08

# gets information on pci information assuming lspci is installed
# I really don't remember how I wrote this originally, so I just put everything
# into the hash (as done in v2), then print the hash. Unneccessarily wasteful of memory

# find our location and use it for searching for libraries
BEGIN {
   use FindBin;
   use File::Spec;
   use lib File::Spec->catdir($FindBin::Bin);
   eval( 'use library;' ); die "Could not find library.pm in the code directory\n" if $@;
   eval( 'use Data::Dumper;' );
}

# check for valid OS. 
exit 1 unless &checkOS( { 'freebsd' => undef } );

# check for required commands, return 2 if they don't exist. Enter an full list of all commands required. If one doesn't exist
# script returns a 2
foreach my $command ( 'pciconfig' ) {
   exit 2 unless &validCommandOnSystem( $command );
}

my $CATEGORY = 'pci';

my @pciInfo =  qx( pciconfig -lv);

my %returnValue;

chomp @pciInfo;
my $slot = '';
while ( my $line = shift( @pciInfo ) ) {
   if ( $line =~ m/^([^@]+)\@([^ ]+)\s+class=([^ ]+)\s+card=([^ ]+)\s+chip=([^ ]+)\s+rev=([^ ]+)\s+hdr=(.+)$/ ) {
      $slot = $2;
      $returnValue{$slot}{'driver'} = $1;
      $returnValue{$slot}{'class'} = $3;
      $returnValue{$slot}{'card'} = $4;
      $returnValue{$slot}{'chip'} = $5;
      $returnValue{$slot}{'revision'} = $6;
      $returnValue{$slot}{'header'} = $7;
   } else {
      my ($key, $value ) = split( '=', $line );
      $returnValue{$slot}{&cleanUp( ' ', $key )} = &cleanUp( ' ', $value );
   }
}


foreach my $key ( sort keys %returnValue ) {
   my $temp = $returnValue{$key};
   foreach my $info ( keys %$temp ) {
      print "$CATEGORY\t$key\t$info\t" . $$temp{$info} . "\n";
   }
}