Subversion Repositories camp_sysinfo_client_3

#!/usr/bin/env perl
use warnings;
use strict;  

use version ; our $VERSION = 'v1.0.0';

# Template for modules to be used in sysinfo
# Author: R. W. Rodolico
# Date:   2017-11-24
#
# gets information on ZFS partitions. Returns them as a hash
#
# Revision History
#
#

# find our location and use it for searching for libraries. library.pm must be in the same directory as the calling script
# or, if run interactively, in the parent of the modules
BEGIN {
   use FindBin;
   use File::Spec;
   # prepend the bin directory and its parent
   use lib File::Spec->catdir($FindBin::Bin), File::Spec->catdir("$FindBin::Bin/..");
   eval( 'use library;' );
   die sprintf( "Could not find library.pm in %s, INC is %s\n", __FILE__, join( "\n", @INC ) ) if $@;
}

#####
##### Change these to match your needs
#####

# Make this a list of all the modules we are going to use. You can replace undef with the version you need, if you like
my $modulesList = {
        'Data::Dumper'     => undef,
   };

# hash of commands that are needed for the system. key is the name of the command and, in some cases, the value will become
# the full path (from which or where)
my $commandsList = {
        'zpool' => undef,
   };

# list of operating systems this module can be used on.
my $osList = {
#         'mswin32' => undef,
         'freebsd' => undef,
         'linux'   => undef,
   };

# the category the return data should go into. See sysinfo for a list
my $CATEGORY = 'diskinfo';

#####
##### End of required
#####

# some variables needed for our system
my $errorPrepend = 'error: in ' . __FILE__; # this is prepended to any error messages
my @out; # temporary location for each line of output

# Try to load the modules we need. If we can not, then make a list of missing modules for error message.
for my $module ( keys %$modulesList ) {
   eval ( "use $module;" );
   push @out, "$errorPrepend Could not load $module" if $@;
}

if ( ! @out && ! checkOS ( $osList ) ) { # check if we are on an acceptible operating system
    push @out, "$errorPrepend Invalid Operating System";
}
if ( !@out && ! validCommandOnSystem ( $commandsList ) ) {
   push @out, "$errorPrepend Can not find some commands needed";
}
if ( !@out ) { # we made it, we have everything, so do the processing
   #####
   ##### Your code starts here. Remember to push all output onto @out
   #####
   
   sub zfsComponents {
      my $zpoolName = shift;
      my @lines = qx( zpool list -pHv $zpoolName );
      my @result;
      shift @lines; # we already have the first line of info
      my @temp = split( "\t", $lines[0] );
      if ( $temp[1] =~ m/raid|mirror/ ) { # we are looking at a parity level, so add it
         push @result, "$CATEGORY\t$zpoolName\tlevel\t$temp[1]";
         shift @lines;
      } else {
         push @result, "$CATEGORY\t$zpoolName\tlevel\tdisk";
      }
      my @out;
      while ( my $temp = shift @lines ) {
         @temp = split( "\t", $temp );
         push @out, $temp[1] if defined $temp[1];
      }
      push @result, "$CATEGORY\t$zpoolName\tcomponents\t" . join( " ", @out );
      return join( "\n", @result ) . "\n";
   }

   # process zfs
   my @devices = qx ( zpool list -pH );
   foreach my $device ( @devices ) {
      chomp $device;
      my ( $name, $size, $allocated, $free, $expandsz, $frag, $cap, $dedup, $health, $altroot ) = split( "\t", $device );
      $size /= 1024;
      $allocated /= 1024;
      $allocated = int( $allocated );
      push @out,  "$CATEGORY\t$name\tfstype\tzfs"; # next is fs type
      push @out,  "$CATEGORY\t$name\tsize\t$size"; # total partition size, in k
      push @out,  "$CATEGORY\t$name\tused\t$allocated"; # disk usage, in k
      push @out,  &zfsComponents( $name );
   } # foreach
   
   #####
   ##### Your code ends here.
   #####
}

# If we are testing from the command line (caller is undef), print the results for debugging
print join( "\n", @out ) . "\n" unless caller;
# called by do, which has a value of the last assignment made, so make the assignment. The equivilent of a return
my $return = join( "\n", @out );